Function: eieio-defclass-autoload

eieio-defclass-autoload is an autoloaded and byte-compiled function defined in eieio-core.el.gz.

Signature

(eieio-defclass-autoload CNAME SUPERCLASSES FILENAME DOC)

Documentation

Create autoload symbols for the EIEIO class CNAME.

SUPERCLASSES are the superclasses that CNAME inherits from. DOC is the docstring for CNAME. This function creates a mock-class for CNAME and adds it into SUPERCLASSES as children. It creates an autoload function for CNAME's constructor.

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/eieio-core.el.gz
;; We autoload this because it's used in `make-autoload'.
;;;###autoload
(defun eieio-defclass-autoload (cname superclasses filename doc)
  "Create autoload symbols for the EIEIO class CNAME.
SUPERCLASSES are the superclasses that CNAME inherits from.
DOC is the docstring for CNAME.
This function creates a mock-class for CNAME and adds it into
SUPERCLASSES as children.
It creates an autoload function for CNAME's constructor."
  ;; Assume we've already debugged inputs.
  (let* ((oldc (cl--find-class cname))
	 (newc (eieio--class-make cname))
	 (parents (mapcar #'cl-find-class superclasses)))
    (if (eieio--class-p oldc)
	nil ;; Do nothing if we already have this class.

      ;; turn this into a usable self-pointing symbol
      (when eieio-backward-compatibility
        (set cname cname)
        (make-obsolete-variable cname (format "use '%s instead" cname) "25.1"))

      (when (memq nil parents)
        ;; If some parents aren't yet fully defined, just ignore them for now.
        (setq parents (delq nil parents)))
      (unless parents
       (setq parents (list (cl--find-class 'eieio-default-superclass))))
      (setf (cl--class-parents newc) parents)
      (setf (cl--find-class cname) newc)

      ;; Create an autoload on top of our constructor function.
      (autoload cname filename doc nil nil)
      (autoload (intern (format "%s-p" cname)) filename "" nil nil)
      (when eieio-backward-compatibility
        (autoload (intern (format "%s-child-p" cname)) filename "" nil nil)))))