Function: embark-verbose-indicator

embark-verbose-indicator is a byte-compiled function defined in embark.el.

Signature

(embark-verbose-indicator)

Documentation

Indicator that displays a table of key bindings in a buffer.

The default display includes the type and value of the current target, the list of other target types, and a table of key bindings, actions and the first line of their docstrings.

The order and formatting of these items is completely configurable through the variable embark-verbose-indicator-buffer-sections.

If the keymap being shown contains prefix keys, the table of key bindings can either show just the prefixes and update once the prefix is pressed, or it can contain a flat list of all full key sequences bound in the keymap. This is controlled by the variable embark-verbose-indicator-nested.

To reduce clutter in the key binding table, one can set the variable embark-verbose-indicator-excluded-actions to a list of symbols and regexps matching commands to exclude from the table.

To configure how a window is chosen to display this buffer, see the variable embark-verbose-indicator-display-action.

Source Code

;; Defined in ~/.emacs.d/elpa/embark-20260610.302/embark.el
(defun embark-verbose-indicator ()
  "Indicator that displays a table of key bindings in a buffer.
The default display includes the type and value of the current
target, the list of other target types, and a table of key
bindings, actions and the first line of their docstrings.

The order and formatting of these items is completely
configurable through the variable
`embark-verbose-indicator-buffer-sections'.

If the keymap being shown contains prefix keys, the table of key
bindings can either show just the prefixes and update once the
prefix is pressed, or it can contain a flat list of all full key
sequences bound in the keymap.  This is controlled by the
variable `embark-verbose-indicator-nested'.

To reduce clutter in the key binding table, one can set the
variable `embark-verbose-indicator-excluded-actions' to a list
of symbols and regexps matching commands to exclude from the
table.

To configure how a window is chosen to display this buffer, see
the variable `embark-verbose-indicator-display-action'."
  (lambda (&optional keymap targets prefix)
    (if (not keymap)
        (when-let* ((win (get-buffer-window embark--verbose-indicator-buffer
                                            'visible)))
          (quit-window 'kill-buffer win))
      (embark--verbose-indicator-update
       (if (and prefix embark-verbose-indicator-nested)
           ;; Lookup prefix keymap globally if not found in action keymap
           (let ((overriding-terminal-local-map keymap))
             (key-binding prefix 'accept-default))
         keymap)
       targets)
      (let ((display-buffer-alist
             `(,@display-buffer-alist
               (,(regexp-quote embark--verbose-indicator-buffer)
                ,@embark-verbose-indicator-display-action))))
        (display-buffer embark--verbose-indicator-buffer)))))