Function: epa-ks--display-keys

epa-ks--display-keys is a byte-compiled function defined in epa-ks.el.gz.

Signature

(epa-ks--display-keys BUF KEYS)

Documentation

Prepare KEYS for tabulated-list-mode, for buffer BUF.

KEYS is a list of epa-ks-key structures, as parsed by epa-ks--parse-buffer.

Source Code

;; Defined in /usr/src/emacs/lisp/epa-ks.el.gz
(defun epa-ks--display-keys (buf keys)
  "Prepare KEYS for `tabulated-list-mode', for buffer BUF.

KEYS is a list of `epa-ks-key' structures, as parsed by
`epa-ks--parse-buffer'."
  (when (buffer-live-p buf)
    (let (entries)
      (dolist (key keys)
        (dolist (name (epa-ks-key-names key))
          (push (list (cons key name)
                      (vector
                       (substring (epa-ks-key-id key) -8)
                       (cdr (epa-ks-key-algo key))
                       (if (epa-ks-key-created key)
                           (format-time-string "%F" (epa-ks-key-created key))
                         "N/A")
                       (if (epa-ks-key-expires key)
                           (let* ((date (epa-ks-key-expires key))
                                  (str (format-time-string "%F" date)))
                             (when (< 0 (time-to-seconds (time-since date)))
                               (setq str (propertize str 'face
                                                     'font-lock-warning-face)))
                             str)
                         (propertize "N/A" 'face 'shadow))
                       (decode-coding-string
                        (epa-ks-name-uid name)
                        (select-safe-coding-system (epa-ks-name-uid name)
                                                   nil 'utf-8))))
                entries)))
      (with-current-buffer buf
        (setq tabulated-list-entries entries)
        (tabulated-list-print t t))
      (message (substitute-command-keys
                "Press \\`f' to mark a key, \\`x' to fetch all marked keys.")))))