Function: epa-mail-sign

epa-mail-sign is an autoloaded, interactive and byte-compiled function defined in epa-mail.el.gz.

Signature

(epa-mail-sign START END SIGNERS MODE)

Documentation

Sign the current buffer.

The buffer is expected to contain a mail message, and signing is performed with your default key. With prefix argument, asks you to select interactively the key to use from your key ring.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/epa-mail.el.gz
;;;###autoload
(defun epa-mail-sign (start end signers mode)
  "Sign the current buffer.
The buffer is expected to contain a mail message, and signing is
performed with your default key.
With prefix argument, asks you to select interactively the key to
use from your key ring."
  (declare (interactive-only t))
  (interactive
   (save-excursion
     (goto-char (point-min))
     (rfc822-goto-eoh)
     (unless (eobp)
       (forward-line))
     (setq epa-last-coding-system-specified
	   (or coding-system-for-write
	       (select-safe-coding-system (point) (point-max))))
     (let ((verbose current-prefix-arg))
       (list (point) (point-max)
	     (if verbose
		 (epa-select-keys (epg-make-context epa-protocol)
				  "Select keys for signing.
If no one is selected, default secret key is used.  "
				  nil t))
	     (if verbose
		 (epa--read-signature-type)
	       'clear)))))
  (let ((inhibit-read-only t))
    (with-suppressed-warnings ((interactive-only epa-sign-region))
      (epa-sign-region start end signers mode))))