Function: erc--querypoll-on-352

erc--querypoll-on-352 is a byte-compiled function defined in erc-notify.el.gz.

Signature

(erc--querypoll-on-352 TARGET-NICK ARGS)

Documentation

Add or update erc-server-users data for TARGET-NICK from ARGS.

Then add user to participant rolls in any existing query buffers.

Source Code

;; Defined in /usr/src/emacs/lisp/erc/erc-notify.el.gz
(defun erc--querypoll-on-352 (target-nick args)
  "Add or update `erc-server-users' data for TARGET-NICK from ARGS.
Then add user to participant rolls in any existing query buffers."
  (pcase-let
      ((`(,_ ,channel ,login ,host ,_server ,nick ,_flags, hop-real) args))
    (when (and (string= channel "*") (erc-nick-equal-p nick target-nick))
      (if-let* ((user (erc-get-server-user nick)))
          (erc-update-user user nick host login
                           (erc--extract-352-full-name hop-real))
        ;; Don't add unless target is already known.
        (when (erc-get-buffer nick erc-server-process)
          (erc-add-server-user
           nick (make-erc-server-user
                 :nickname nick :login login :host host
                 :full-name (erc--extract-352-full-name hop-real)))))
      (erc--ensure-query-member nick)
      t)))