Function: erc--recon-probe-reschedule

erc--recon-probe-reschedule is a byte-compiled function defined in erc-backend.el.gz.

Signature

(erc--recon-probe-reschedule PROC)

Documentation

Print a message saying PROC's intended peer can't be reached.

Then call erc-schedule-reconnect.

Source Code

;; Defined in /usr/src/emacs/lisp/erc/erc-backend.el.gz
(defun erc--recon-probe-reschedule (proc)
  "Print a message saying PROC's intended peer can't be reached.
Then call `erc-schedule-reconnect'."
  (let ((buffer (or (and-let* ((proc)
                               (buffer (process-buffer proc))
                               ((buffer-live-p buffer))
                               (buffer)))
                    (current-buffer))))
    (with-current-buffer buffer
      (let ((erc-server-reconnect-timeout
             (or erc--server-reconnect-timeout
                 erc-server-reconnect-timeout)))
        (when (and proc (not (eq proc erc-server-process)))
          (set-process-sentinel proc #'ignore)
          (delete-process proc))
        (erc-display-message nil '(notice error) buffer
                             'recon-probe-nobody-home)
        (erc-schedule-reconnect buffer 0)))))