Function: erc-connection-established

erc-connection-established is a byte-compiled function defined in erc.el.gz.

Signature

(erc-connection-established PROC PARSED)

Documentation

Set user mode and run erc-after-connect hook in server buffer.

Source Code

;; Defined in /usr/src/emacs/lisp/erc/erc.el.gz
(defun erc-connection-established (proc parsed)
  "Set user mode and run `erc-after-connect' hook in server buffer."
  (with-current-buffer (process-buffer proc)
    (unless erc-server-connected ; only once per session
      (let ((server (or erc-server-announced-name
                        (erc-response.sender parsed)))
            (nick (car (erc-response.command-args parsed)))
            (buffer (process-buffer proc)))
        (setq erc-server-connected t)
        (setq erc--server-last-reconnect-count erc-server-reconnect-count
              erc-server-reconnect-count 0)
        (setq erc--server-reconnect-display-timer
              (run-at-time erc-auto-reconnect-display-timeout nil
                           #'erc--server-last-reconnect-display-reset
                           (current-buffer)))
        (add-hook 'erc-disconnected-hook
                  #'erc--server-last-reconnect-on-disconnect nil t)
        (erc-update-mode-line)
        (erc-set-initial-user-mode nick buffer)
        (erc-server-setup-periodical-ping buffer)
        ;; Run mode hooks on all reclaimed query buffers.
        (let ((buffer (current-buffer))
              (erc-join-buffer 'bury)
              erc-active-buffer)
          (erc-with-all-buffers-of-server erc-server-process
              #'erc-query-buffer-p
            (let ((target (erc-target)))
              (with-current-buffer buffer
                (erc--open-target target)))
            (when erc-unhide-query-prompt
              (erc--unhide-prompt))))
        (run-hook-with-args 'erc-after-connect server nick)))))