Function: erc-settings-disable

erc-settings-disable is an interactive and byte-compiled function defined in erc-settings.el.gz.

Signature

(erc-settings-disable)

Documentation

Disable ERC settings mode.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/erc/erc-settings.el.gz
;;;###autoload(autoload 'erc-settings-mode "erc-settings" nil t)
(define-erc-module settings nil
  "Global module to set ERC options locally per-buffer.
Like many modules, this cannot reasonably be toggled via mode command
mid-session.  To see the result of updates to the option `erc-settings'
immediately, destroy and reopen all affected sessions."
  ((when (and erc--updating-modules-p
              (not (memq #'erc-settings--set-modules
                         (default-value 'erc--set-modules-functions))))
     (erc--warn-once-before-connect 'erc-settings-mode
       "Module `settings' did not load properly. Add it to `erc-modules'"
       " and run `erc-update-modules' before connecting, or use a"
       " Custom-aware configuration method, like `setopt'."))
   ;; Set non-`erc-module' entries in target buffers after all default
   ;; non-connection related local session variables have been set.
   (if erc--updating-modules-p
       (add-hook 'change-major-mode-after-body-hook
                 #'erc-settings--setup -90 t)
     (erc-buffer-do #'erc-settings--setup))
   ;; Set any remaining entries in server buffers once the network is
   ;; known and all local session variables have been populated.
   (add-hook 'erc-after-connect #'erc-settings-bind -30)
   (add-hook 'erc--set-modules-functions #'erc-settings--set-modules 30))
  ((erc-buffer-do #'erc-settings--setup)
   (remove-hook 'erc-after-connect #'erc-settings-bind)
   (remove-hook 'erc--set-modules-functions #'erc-settings--set-modules)))