Function: ert--insert-infos

ert--insert-infos is a byte-compiled function defined in ert.el.gz.

Signature

(ert--insert-infos RESULT)

Documentation

Insert ert-info infos from RESULT into current buffer.

RESULT must be an ert-test-result-with-condition.

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/ert.el.gz
(defun ert--insert-infos (result)
  "Insert `ert-info' infos from RESULT into current buffer.

RESULT must be an `ert-test-result-with-condition'."
  (cl-check-type result ert-test-result-with-condition)
  (dolist (info (ert-test-result-with-condition-infos result))
    (cl-destructuring-bind (prefix . message) info
      (let ((begin (point))
            (indentation (make-string (+ (length prefix) 4) ?\s))
            (end nil))
        (unwind-protect
            (progn
              (when (functionp message)
                (setq message (funcall message)))
              (insert message "\n")
              (setq end (point-marker))
              (goto-char begin)
              (insert "    " prefix)
              (forward-line 1)
              (while (< (point) end)
                (insert indentation)
                (forward-line 1)))
          (when end (set-marker end nil)))))))