Function: evil-visual-restore

evil-visual-restore is an interactive and byte-compiled function defined in evil-commands.el.

Signature

(evil-visual-restore)

Documentation

Restore previous selection.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/evil-20251108.138/evil-commands.el
;;; Visual commands

(evil-define-motion evil-visual-restore ()
  "Restore previous selection."
  (cond
   ;; Called from visual state
   ((and (evil-visual-state-p)
         evil-prev-visual-mark evil-prev-visual-point evil-prev-visual-selection)
    (let ((tmp-visual-mark (marker-position evil-visual-mark))
          (tmp-visual-point (marker-position evil-visual-point))
          (tmp-visual-selection evil-visual-selection))
      (evil-visual-make-selection evil-prev-visual-mark
                                  evil-prev-visual-point
                                  evil-prev-visual-selection
                                  t)
      (move-marker evil-prev-visual-mark tmp-visual-mark)
      (move-marker evil-prev-visual-point tmp-visual-point)
      (setq evil-prev-visual-selection tmp-visual-selection)))
   ;; Called from other state
   ((and evil-visual-selection evil-visual-mark evil-visual-point)
    (evil-visual-make-selection evil-visual-mark
                                evil-visual-point
                                (evil-visual-type)
                                t))))