Function: fill-flowed-encode

fill-flowed-encode is an autoloaded and byte-compiled function defined in flow-fill.el.gz.

Signature

(fill-flowed-encode &optional BUFFER)

Source Code

;; Defined in /usr/src/emacs/lisp/mail/flow-fill.el.gz
;;;###autoload
(defun fill-flowed-encode (&optional buffer)
  (with-current-buffer (or buffer (current-buffer))
    ;; No point in doing this unless hard newlines is used.
    (when use-hard-newlines
      (let ((start (point-min)) end)
	;; Go through each paragraph, filling it and adding SPC
	;; as the last character on each line.
	(while (and (< start (point-max))
                    (setq end (or (text-property-any start (point-max) 'hard 't)
                                  (point-max))))
	  (save-restriction
	    (narrow-to-region start end)
	    (let ((fill-column (eval fill-flowed-encode-column t)))
	      (fill-flowed-fill-buffer))
	    (goto-char (point-min))
	    (while (re-search-forward "\n" nil t)
	      (replace-match " \n" t t))
	    (goto-char (setq start (1+ (point-max)))))))
      t)))