Function: flymake--update-current-eol-overlay

flymake--update-current-eol-overlay is a byte-compiled function defined in flymake.el.gz.

Signature

(flymake--update-current-eol-overlay)

Documentation

Maybe paint nearby eol diagnostics with special current-* styles.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/flymake.el.gz
(cl-defun flymake--update-current-eol-overlay
    (&aux style-entry (fid flymake-inline-diagnostics)
          (old-o flymake--eol-current-overlay))
  "Maybe paint nearby eol diagnostics with special `current-*' styles."
  (when (and (consp fid)
             (setq style-entry (or (assoc 'current fid)
                                   (assoc 'current-line fid)))
             ;; JT@2026-08-09: Don't consider current/current-line
             ;; entries if a region is active or a flymake hasn't
             ;; finished.  FIXME: An active in-buffer completion session
             ;; should probably also have the same inhibiting effect,
             ;; but at time of writing there is no easy way to answer
             ;; that question.
             (not (region-active-p))
             (not flymake-timer))
    (cl-loop
     for style = (cdr style-entry)
     for o in (overlays-at (line-end-position))
     for src-ovs = (overlay-get o 'flymake-eol-source-overlays)
     when (and src-ovs
               (or (eq (car style-entry) 'current-line)
                   (cl-some (lambda (o) (<= (overlay-start o) (point)
                                            (overlay-end o)))
                            src-ovs)))
     do
     (unless (eq o old-o)
       (when (and old-o (overlay-buffer old-o))
         (overlay-put old-o 'display (flymake--eol-overlay-summary old-o)))
       (overlay-put o 'display (flymake--eol-overlay-summary o style))
       (setq flymake--eol-current-overlay o))
     (cl-return-from flymake--update-current-eol-overlay))
    (when old-o
      (overlay-put old-o 'display (flymake--eol-overlay-summary old-o))
      (setq flymake--eol-current-overlay nil))))