Function: font-latex--get-script-props

font-latex--get-script-props is a byte-compiled function defined in font-latex.el.

Signature

(font-latex--get-script-props POS SCRIPT-TYPE)

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/font-latex.el
(defun font-latex--get-script-props (pos script-type)
  (let* ((old-raise (or (plist-get (get-text-property pos 'display) 'raise) 0.0))
         (new-level (1+ (or (get-text-property pos 'script-level) 0)))
         (disp-props (copy-sequence (cl-case script-type
                                      (:super (cdr font-latex-script-display))
                                      (:sub   (car font-latex-script-display)))))
         (new-disp-props (let ((raise (plist-get disp-props 'raise))
                               (nl new-level))
                           (if raise
                               ;; This polynom approximates that the factor
                               ;; which is multiplied with raise is 1 for nl=1,
                               ;; 0.8 for nl=2, 0.64 for nl=3, etc. (so always
                               ;; about 80% of the previous value).
                               (plist-put disp-props 'raise
                                          (+ old-raise
                                             (* raise
                                                (+ 1.1965254857142873
                                                   (* nl -0.21841226666666758)
                                                   (* nl nl 0.012018514285714385)))))
                             disp-props))))
    `(face ,(if (<= new-level font-latex-fontify-script-max-level)
                (cl-case script-type
                  (:super 'font-latex-superscript-face)
                  (:sub   'font-latex-subscript-face))
              nil)
           script-level ,new-level
           display ,new-disp-props)))