Function: frame--complete-parameter-value

frame--complete-parameter-value is a byte-compiled function defined in frame.el.gz.

Signature

(frame--complete-parameter-value WIDGET)

Documentation

Provide completion for WIDGET, which holds frame parameter's values.

Source Code

;; Defined in /usr/src/emacs/lisp/frame.el.gz
(defun frame--complete-parameter-value (widget)
  "Provide completion for WIDGET, which holds frame parameter's values."
  (let* ((parameter (widget-value
                     (nth 0
                          (widget-get (widget-get widget :parent) :children))))
         (comps (cond ((eq parameter 'display-type)
                       '("color" "grayscale" "mono"))
                      ((eq parameter 'z-group) '("nil" "above" "below"))
                      ((memq parameter '(fullscreen fullscreen-restore))
                       '("fullwidth" "fullheight" "fullboth" "maximized"))
                      ((eq parameter 'cursor-type)
                       '("t" "nil" "box" "hollow" "bar" "hbar"))
                      ((eq parameter 'vertical-scroll-bars)
                       '("nil" "left" "right"))
                      ((eq parameter 'tool-bar-position)
                       '("top" "bottom" "left" "right"))
                      ((eq parameter 'minibuffer)
                       '("t" "nil" "only"))
                      ((eq parameter 'minibuffer-exit)
                       '("nil" "t" "iconify-frame" "delete-frame"))
                      ((eq parameter 'visibility) '("nil" "t" "icon"))
                      ((memq parameter '(ns-appearance background-mode))
                       '("dark" "light"))
                      ((eq parameter 'font-backend)
                       '("x" "xft" "xfthb" "ftcr" "ftcrhb" "gdi"
                         "uniscribe" "harfbuzz"))
                      ((memq parameter '(buffer-predicate auto-hide-function))
                       (apply-partially
                        #'completion-table-with-predicate
                        obarray #'fboundp 'strict))
                      (t nil))))
    (completion-in-region (widget-field-start widget)
                          (max (point) (widget-field-text-end widget))
                          comps)))