Function: gdb-breakpoints--add-breakpoint-row

gdb-breakpoints--add-breakpoint-row is a byte-compiled function defined in gdb-mi.el.gz.

Signature

(gdb-breakpoints--add-breakpoint-row TBL BKPT)

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/gdb-mi.el.gz
(defun gdb-breakpoints--add-breakpoint-row (tbl bkpt)
  (let ((at (gdb-mi--field bkpt 'at))
        (pending (gdb-mi--field bkpt 'pending))
        (addr (gdb-mi--field bkpt 'addr))
        (func (gdb-mi--field bkpt 'func))
	(type (gdb-mi--field bkpt 'type)))
    (if (and (not func) (string-equal addr "<MULTIPLE>"))
        (setq func ""))
    (gdb-table-add-row tbl
                       (list
                        (gdb-mi--field bkpt 'number)
                        (or type "")
                        (or (gdb-mi--field bkpt 'disp) "")
                        (let ((flag (gdb-mi--field bkpt 'enabled)))
                          (if (string-equal flag "y")
                              (eval-when-compile
                                (propertize "y" 'font-lock-face
                                            'font-lock-warning-face))
                            (eval-when-compile
                              (propertize "n" 'font-lock-face
                                          'font-lock-comment-face))))
                        addr
                        (or (gdb-mi--field bkpt 'times) "")
                        (if (and type (string-match ".*watchpoint" type))
                            (gdb-mi--field bkpt 'what)
                          (or (and (equal func "") "")
                              pending at
                              (concat "in "
                                      (propertize (or func "unknown")
                                                  'font-lock-face
                                                  'font-lock-function-name-face)
                                      (gdb-frame-location bkpt)))))
                       ;; Add clickable properties only for
                       ;; breakpoints with file:line information
                       (append (list 'gdb-breakpoint bkpt)
                               (when func
                                 '(help-echo "mouse-2, RET: visit breakpoint"
                                             mouse-face highlight))))))