Function: gnus-article-get-xrefs

gnus-article-get-xrefs is a byte-compiled function defined in gnus-sum.el.gz.

Signature

(gnus-article-get-xrefs)

Documentation

Fill in the Xref value in gnus-current-headers, if necessary.

This is meant to be called in gnus-article-internal-prepare-hook.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-sum.el.gz
(defun gnus-article-get-xrefs ()
  "Fill in the Xref value in `gnus-current-headers', if necessary.
This is meant to be called in `gnus-article-internal-prepare-hook'."
  (let ((headers (with-current-buffer gnus-summary-buffer
		   gnus-current-headers)))
    (or (not gnus-use-cross-reference)
	(not headers)
	(and (mail-header-xref headers)
	     (not (string= (mail-header-xref headers) "")))
	(let ((case-fold-search t)
	      xref)
	  (save-restriction
	    (nnheader-narrow-to-headers)
	    (goto-char (point-min))
	    (when (or (and (not (eobp))
			   (eq (downcase (char-after)) ?x)
			   (looking-at "Xref:"))
		      (search-forward "\nXref:" nil t))
	      (goto-char (1+ (match-end 0)))
              (setq xref (buffer-substring (point) (line-end-position)))
	      (setf (mail-header-xref headers) xref)))))))