Function: gnus-article-next-page

gnus-article-next-page is an autoloaded, interactive and byte-compiled function defined in gnus-art.el.gz.

Signature

(gnus-article-next-page &optional LINES)

Documentation

Show the next page of the current article.

If end of article, return non-nil. Otherwise return nil. Argument LINES specifies lines to be scrolled up.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-art.el.gz
;; This is cleaner but currently breaks `gnus-pick-mode':
;;
;; (defun gnus-article-goto-next-page ()
;;   "Show the next page of the article."
;;   (interactive)
;;   (gnus-eval-in-buffer-window gnus-summary-buffer
;;     (gnus-summary-next-page)))
;;
;; (defun gnus-article-goto-prev-page ()
;;   "Show the next page of the article."
;;   (interactive)
;;   (gnus-eval-in-buffer-window gnus-summary-buffer
;;     (gnus-summary-prev-page)))

(defun gnus-article-next-page (&optional lines)
  "Show the next page of the current article.
If end of article, return non-nil.  Otherwise return nil.
Argument LINES specifies lines to be scrolled up."
  (interactive "p" gnus-article-mode)
  (move-to-window-line (- -1 scroll-margin))
  (if (and (not (and gnus-article-over-scroll
		     (> (count-lines (window-start) (point-max))
			(+ (or lines (1- (window-height))) scroll-margin))))
	   (save-excursion
	     (end-of-line)
	     (and (pos-visible-in-window-p)	;Not continuation line.
		  (>= (point) (point-max)))))
      ;; Nothing in this page.
      (if (or (not gnus-page-broken)
	      (save-excursion
		(save-restriction
		  (widen)
		  (forward-line)
		  (eobp)))) ;Real end-of-buffer?
	  (progn
	    (when gnus-article-over-scroll
	      (gnus-article-next-page-1 lines))
	    t)			;Nothing more.
	(gnus-narrow-to-page 1)		;Go to next page.
	nil)
    ;; More in this page.
    (gnus-article-next-page-1 lines)
    nil))