Function: gnus-article-prepare-display

gnus-article-prepare-display is an autoloaded and byte-compiled function defined in gnus-art.el.gz.

Signature

(gnus-article-prepare-display)

Documentation

Make the current buffer look like a nice article.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-art.el.gz
;;;###autoload
(defun gnus-article-prepare-display ()
  "Make the current buffer look like a nice article."
  ;; Hooks for getting information from the article.
  ;; This hook must be called before being narrowed.
  (let ((gnus-article-buffer (current-buffer))
	buffer-read-only
	(inhibit-read-only t))
    (unless (derived-mode-p 'gnus-article-mode)
      (gnus-article-mode))
    (setq buffer-read-only nil
	  gnus-article-wash-types nil
	  gnus-article-image-alist nil)
    (gnus-run-hooks 'gnus-tmp-internal-hook)
    (when gnus-display-mime-function
      (funcall gnus-display-mime-function))
    ;; Add attachment buttons to the header.
    (when gnus-mime-display-attachment-buttons-in-header
      (gnus-mime-buttonize-attachments-in-header))))