Function: gnus-button-fetch-group

gnus-button-fetch-group is a byte-compiled function defined in gnus-art.el.gz.

Signature

(gnus-button-fetch-group ADDRESS &rest IGNORE)

Documentation

Fetch GROUP specified by ADDRESS.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-art.el.gz
(defun gnus-button-fetch-group (address &rest _ignore)
  "Fetch GROUP specified by ADDRESS."
  (when (string-match "\\`\\(nntp\\|news\\):\\(//\\)?\\(.*\\)\\'"
		      address)
    ;; Allow to use `gnus-button-fetch-group' in `browse-url-browser-function'
    ;; for nntp:// and news://
    (setq address (match-string 3 address)))
  (if (not (string-match "[:/]" address))
      ;; This is just a simple group url.
      (gnus-group-read-ephemeral-group address gnus-select-method)
    (if (not
	 (string-match
	  "^\\([^:/]+\\)\\(:\\([^/]+\\)\\)?/\\([^/]+\\)\\(/\\([0-9]+\\)\\)?"
	  address))
	(error "Can't parse %s" address)
      (gnus-group-read-ephemeral-group
       (match-string 4 address)
       `(nntp ,(match-string 1 address)
	      (nntp-address ,(match-string 1 address))
	      (nntp-port-number ,(if (match-end 3)
				     (match-string 3 address)
				   "nntp")))
       nil nil nil
       (and (match-end 6) (list (string-to-number (match-string 6 address))))))))