Function: gnus-fetch-headers

gnus-fetch-headers is a byte-compiled function defined in gnus-sum.el.gz.

Signature

(gnus-fetch-headers ARTICLES &optional LIMIT FORCE-NEW DEPENDENCIES)

Documentation

Fetch headers of ARTICLES.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-sum.el.gz
(defun gnus-fetch-headers (articles &optional limit force-new dependencies)
  "Fetch headers of ARTICLES."
  (gnus-message 7 "Fetching headers for %s..." gnus-newsgroup-name)
  (prog1
      (pcase (setq gnus-headers-retrieved-by
		   (gnus-retrieve-headers
		    articles gnus-newsgroup-name
		    (or limit
			;; We might want to fetch old headers, but
			;; not if there is only 1 article.
			(and (or (and
				  (not (eq gnus-fetch-old-headers 'some))
				  (not (numberp gnus-fetch-old-headers)))
				 (> (length articles) 1))
			     gnus-fetch-old-headers))))
    ('nov
     (gnus-get-newsgroup-headers-xover
      articles force-new dependencies gnus-newsgroup-name t))
    ('headers
     (gnus-get-newsgroup-headers dependencies force-new))
    ((pred listp)
     (let ((dependencies
	    (or dependencies
		(with-current-buffer gnus-summary-buffer
		  gnus-newsgroup-dependencies))))
       (delq nil (mapcar (lambda (header)
                           (gnus-dependencies-add-header
                            header dependencies force-new))
			 gnus-headers-retrieved-by)))))
  (gnus-message 7 "Fetching headers for %s...done" gnus-newsgroup-name)))