Function: gnus-find-method-for-group

gnus-find-method-for-group is a byte-compiled function defined in gnus.el.gz.

Signature

(gnus-find-method-for-group GROUP &optional INFO)

Documentation

Find the select method that GROUP uses.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus.el.gz
(defun gnus-find-method-for-group (group &optional info)
  "Find the select method that GROUP uses."
  (or gnus-override-method
      (and (not group)
	   gnus-select-method)
      (and (not (gnus-group-entry group))
	   ;; Killed or otherwise unknown group.
	   (or
	    ;; If we know a virtual server by that name, return its method.
	    (gnus-server-to-method (gnus-group-server group))
	    ;; Guess a new method as last resort.
	    (gnus-group-name-to-method group)))
      (let ((info (or info (gnus-get-info group)))
	    method)
	(if (or (not info)
		(not (setq method (gnus-info-method info)))
		(equal method "native"))
	    gnus-select-method
	  (setq method
		(cond ((stringp method)
		       (inline (gnus-server-to-method method)))
		      ((stringp (cadr method))
		       (or
			(inline
			 (gnus-same-method-different-name method))
			(inline (gnus-server-extend-method group method))))
		      (t
		       method)))
	  (cond ((equal (cadr method) "")
		 method)
		((null (cadr method))
		 (list (car method) ""))
		(t
		 (gnus-server-add-address method)))))))