Function: gnus-highlight-selected-summary

gnus-highlight-selected-summary is a byte-compiled function defined in gnus-sum.el.gz.

Signature

(gnus-highlight-selected-summary)

Documentation

Highlight selected article in summary buffer.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-sum.el.gz
;;;
;;; summary highlights
;;;

(defun gnus-highlight-selected-summary ()
  "Highlight selected article in summary buffer."
  ;; Added by Per Abrahamsen <amanda@iesd.auc.dk>.
  (when gnus-summary-selected-face
    (save-excursion
      (let* ((beg (line-beginning-position))
             (end (line-end-position))
	     ;; Fix by Mike Dugan <dugan@bucrf16.bu.edu>.
	     (from (if (get-text-property beg 'mouse-face)
		       beg
		     (or (next-single-property-change
			  beg 'mouse-face nil end)
			 beg)))
	     (to
	      (if (= from end)
		  (- from 2)
		(or (next-single-property-change
		     from 'mouse-face nil end)
		    end))))
	;; If no mouse-face prop on line we will have to = from = end,
	;; so we highlight the entire line instead.
	(when (= (+ to 2) from)
	  (setq from beg)
	  (setq to (1+ end)))
	(if gnus-newsgroup-selected-overlay
	    ;; Move old overlay.
	    (move-overlay
	     gnus-newsgroup-selected-overlay from to (current-buffer))
	  ;; Create new overlay.
	  (overlay-put
	   (setq gnus-newsgroup-selected-overlay (make-overlay from to))
	   'face gnus-summary-selected-face))))))