Function: gnus-mime-set-charset-parameters

gnus-mime-set-charset-parameters is a byte-compiled function defined in gnus-art.el.gz.

Signature

(gnus-mime-set-charset-parameters HANDLE CHARSET)

Documentation

Set CHARSET to parameters in HANDLE.

CHARSET may either be a string or a symbol.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-art.el.gz
(defun gnus-mime-set-charset-parameters (handle charset)
  "Set CHARSET to parameters in HANDLE.
CHARSET may either be a string or a symbol."
  (unless (stringp charset)
    (setq charset (symbol-name charset)))
  (if (stringp (car handle))
      (dolist (h (cdr handle))
	(gnus-mime-set-charset-parameters h charset))
    (let* ((type (mm-handle-type (if (equal (mm-handle-media-type handle)
					    "message/external-body")
				     (progn
				       (unless (mm-handle-cache handle)
					 (mm-extern-cache-contents handle))
				       (mm-handle-cache handle))
				   handle)))
	   (param (assq 'charset (cdr type))))
      (if param
	  (setcdr param charset)
	(setcdr type (cons (cons 'charset charset) (cdr type)))))))