Function: gnus-score-load-files

gnus-score-load-files is a byte-compiled function defined in gnus-score.el.gz.

Signature

(gnus-score-load-files SCORE-FILES)

Documentation

Load all score files in SCORE-FILES.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-score.el.gz
(defun gnus-score-load-files (score-files)
  "Load all score files in SCORE-FILES."
  ;; Load the score files.
  (let (scores)
    (while score-files
      (if (stringp (car score-files))
	  ;; It is a string, which means that it's a score file name,
	  ;; so we load the score file and add the score alist to
	  ;; the list of alists.
	  (setq scores (nconc (gnus-score-load-file (car score-files)) scores))
	;; It is an alist, so we just add it to the list directly.
	(setq scores (nconc (car score-files) scores)))
      (setq score-files (cdr score-files)))
    ;; Prune the score files that are to be excluded, if any.
    (when gnus-scores-exclude-files
      (let ((s scores)
	    c)
	(while s
	  (and (setq c (rassq (car s) gnus-score-cache))
	       (member (car c) gnus-scores-exclude-files)
	       (setq scores (delq (car s) scores)))
	  (setq s (cdr s)))))
    scores))