Function: gnus-score-score-files-1

gnus-score-score-files-1 is a byte-compiled function defined in gnus-score.el.gz.

Signature

(gnus-score-score-files-1 DIR)

Documentation

Return all possible score files under DIR.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-score.el.gz
(defun gnus-score-score-files-1 (dir)
  "Return all possible score files under DIR."
  (let ((files (list (expand-file-name dir)))
	(regexp (gnus-score-file-regexp))
	(case-fold-search nil)
	seen out file)
    (while (setq file (pop files))
      (cond
       ;; Ignore files that start with a dot.
       ((string-match "^\\." (file-name-nondirectory file))
	nil)
       ;; Add subtrees of directory to also be searched.
       ((and (file-directory-p file)
	     (not (member (file-truename file) seen)))
	(push (file-truename file) seen)
	(setq files (nconc (directory-files file t nil t) files)))
       ;; Add files to the list of score files.
       ((string-match regexp file)
	(push file out))))
    (or out
	;; Return a dummy value.
	(list (expand-file-name "this.file.does.not.exist.SCORE"
				gnus-kill-files-directory)))))