Function: gnus-topic-goto-missing-group

gnus-topic-goto-missing-group is a byte-compiled function defined in gnus-topic.el.gz.

Signature

(gnus-topic-goto-missing-group GROUP)

Documentation

Place point where GROUP is supposed to be inserted.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-topic.el.gz
(defun gnus-topic-goto-missing-group (group)
  "Place point where GROUP is supposed to be inserted."
  (let* ((topic (gnus-group-topic group))
	 (groups (cdr (assoc topic gnus-topic-alist)))
	 (g (cdr (member group groups)))
	 (unfound t))
    ;; Try to jump to a visible group.
    (while (and g
		(not (gnus-group-goto-group (car g) t)))
      (pop g))
    ;; It wasn't visible, so we try to see where to insert it.
    (when (not g)
      (setq g (cdr (member group (reverse groups))))
      (while (and g unfound)
	(when (gnus-group-goto-group (pop g) t)
	  (forward-line 1)
	  (setq unfound nil)))
      (when (and unfound
		 topic
		 (not (gnus-topic-goto-missing-topic topic)))
	(gnus-topic-display-missing-topic topic)))))