Function: highlight-function-calls--matcher

highlight-function-calls--matcher is a byte-compiled function defined in highlight-function-calls.el.

Signature

(highlight-function-calls--matcher END)

Documentation

Match function symbols up to END.

The matcher function to be used by font lock mode.

Source Code

;; Defined in ~/.emacs.d/elpa/highlight-function-calls-20240922.1826/highlight-function-calls.el
(defun highlight-function-calls--matcher (end)
  "Match function symbols up to END.
The matcher function to be used by font lock mode."
  (catch 'highlight-function-calls--matcher
    (when (not (nth 5 (syntax-ppss)))
      (while (re-search-forward (rx symbol-start (*? any) symbol-end) end t)
        (let ((match (intern-soft (match-string 0))))
          (when (and (or (functionp match)
                         (when highlight-function-calls-macro-calls
                           (macrop match))
                         (when highlight-function-calls-special-forms
                           (special-form-p match)))
                     (not (member match highlight-function-calls-exclude-symbols)))
            (goto-char (match-end 0))
            (setq highlight-function-calls--face-name
                  (pcase match
                    ((and (or 'not 'null) (guard highlight-function-calls-not)) 'highlight-function-calls--not-face)
                    (_ 'highlight-function-calls-face)))
            (throw 'highlight-function-calls--matcher t)))))
    nil))