Function: holiday-bahai-twin-holy-birthdays

holiday-bahai-twin-holy-birthdays is a byte-compiled function defined in cal-bahai.el.gz.

Signature

(holiday-bahai-twin-holy-birthdays)

Documentation

Holiday entries for the Twin Holy Birthdays, if visible in the calendar.

The Birth of the Báb and Birth of Bahá’u’lláh are celebrated on consecutive days. From 172 BE onwards, these dates are determined by the eighth new moon after Naw-Rúz; before that, they were fixed at October 20 and November 12.

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/cal-bahai.el.gz
;;;###holiday-autoload
(defun holiday-bahai-twin-holy-birthdays ()
  "Holiday entries for the Twin Holy Birthdays, if visible in the calendar.
The Birth of the Báb and Birth of Bahá’u’lláh are celebrated on
consecutive days.  From 172 BE onwards, these dates are determined
by the eighth new moon after Naw-Rúz; before that, they were fixed
at October 20 and November 12."
  (let* ((bahai-year (- displayed-year (1- 1844)))
         result)
    (if (>= bahai-year calendar-bahai-reform-year)
        ;; Post-reform: calculate from eighth new moon
        (let* ((dates (calendar-bahai-twin-holy-birthdays-for-year bahai-year))
               (bab-date (car dates))
               (baha-date (cadr dates)))
          (when (calendar-date-is-visible-p bab-date)
            (push (list bab-date "Birth of the Báb") result))
          (when (calendar-date-is-visible-p baha-date)
            (push (list baha-date "Birth of Bahá’u’lláh") result)))
      ;; Pre-reform: fixed dates
      (let ((bab-date (list 10 20 displayed-year))
            (baha-date (list 11 12 displayed-year)))
        (when (calendar-date-is-visible-p bab-date)
          (push (list bab-date "Birth of the Báb") result))
        (when (calendar-date-is-visible-p baha-date)
          (push (list baha-date "Birth of Bahá’u’lláh") result))))
    (nreverse result)))