Function: hui-select-goto-matching-delimiter

hui-select-goto-matching-delimiter is an autoloaded, interactive and byte-compiled function defined in hui-select.el.

Signature

(hui-select-goto-matching-delimiter)

Documentation

Jump back and forth between the start and end delimiters of a thing.

If the key that invokes this command in hyperbole-minor-mode is also bound in the current major mode map, then interactively invoke that command instead. Typically prevents clashes over
{\C-c .}.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/hyperbole-20260414.325/hui-select.el
;;;###autoload
(defun hui-select-goto-matching-delimiter ()
  "Jump back and forth between the start and end delimiters of a thing.

If the key that invokes this command in `hyperbole-minor-mode' is
also bound in the current major mode map, then interactively
invoke that command instead.  Typically prevents clashes over
{\\`C-c' .}."
  (interactive)
  (if (memq major-mode hui-select-markup-modes)
      (hui-select-goto-matching-tag)
    (let* ((key (hypb:cmd-key-vector #'hui-select-goto-matching-delimiter
				     hyperbole-mode-map))
	   (major-mode-binding (lookup-key (current-local-map) key))
	   (this-key-flag (and (called-interactively-p 'any)
			       (equal (this-single-command-keys) key))))
      (cond ((and major-mode-binding (not (integerp major-mode-binding))
		  this-key-flag)
	     ;; If the key that invokes this command in `hyperbole-minor-mode'
	     ;; is also bound in the current major mode map, then
	     ;; interactively invoke that command instead.  Typically
	     ;; prevents clashes over {C-c .}.
	     (call-interactively major-mode-binding))
	    ((and (preceding-char) (or (= ?\) (char-syntax (preceding-char)))
				       (= ?\" (preceding-char))))
	     (backward-sexp))
	    ((and (following-char) (or (= ?\( (char-syntax (following-char)))
				       (= ?\" (following-char))))
	     (forward-sexp))))))