Function: inferior-octave-directory-tracker

inferior-octave-directory-tracker is a byte-compiled function defined in octave.el.gz.

Signature

(inferior-octave-directory-tracker STRING)

Documentation

Tracks cd commands issued to the inferior Octave process.

Use M-x inferior-octave-resync-dirs (inferior-octave-resync-dirs) to resync if Emacs gets confused.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/octave.el.gz
(defun inferior-octave-directory-tracker (string)
  "Tracks `cd' commands issued to the inferior Octave process.
Use \\[inferior-octave-resync-dirs] to resync if Emacs gets confused."
  (when inferior-octave-directory-tracker-resync
    (or (inferior-octave-resync-dirs 'noerror)
        (setq inferior-octave-directory-tracker-resync nil)))
  (cond
   ((string-match "^[ \t]*cd[ \t;]*$" string)
    (cd "~"))
   ((string-match "^[ \t]*cd[ \t]+\\([^ \t\n;]*\\)[ \t\n;]*" string)
    (condition-case err
        (cd (match-string 1 string))
      (error (setq inferior-octave-directory-tracker-resync t)
             (message "%s: `%s'"
                      (error-message-string err)
                      (match-string 1 string)))))))