Function: inferior-octave-mode

inferior-octave-mode is an interactive and byte-compiled function defined in octave.el.gz.

Signature

(inferior-octave-mode)

Documentation

Major mode for interacting with an inferior Octave process.

See Info node (octave-mode) Running Octave from Within Emacs for more details.

Key bindings:
<delete> delete-forward-char
<kp-delete> delete-forward-char
<mouse-2> comint-insert-input
C-<down> comint-next-input
C-<up> comint-previous-input
C-M-l comint-show-output
C-c . comint-insert-previous-argument
C-c C-\ comint-quit-subjob
C-c C-a comint-bol-or-process-mark
C-c C-c comint-interrupt-subjob
C-c C-d comint-send-eof
C-c C-e comint-show-maximum-output
C-c C-l comint-dynamic-list-input-ring
C-c C-l inferior-octave-dynamic-list-input-ring
C-c C-n comint-next-prompt
C-c C-o comint-delete-output
C-c C-p comint-previous-prompt
C-c C-r comint-show-output
C-c C-s comint-write-output
C-c C-u comint-kill-input
C-c C-w backward-kill-word
C-c C-x comint-get-next-from-history
C-c C-z comint-stop-subjob
C-c M-o comint-clear-buffer
C-c M-r comint-previous-matching-input-from-input
C-c M-s comint-next-matching-input-from-input
C-c RET comint-copy-old-input
C-c SPC comint-accumulate
C-d comint-delchar-or-maybe-eof
C-h a octave-lookfor
C-h d octave-help
C-x <up> comint-complete-input-ring
M-. octave-find-definition
M-? comint-dynamic-list-filename-completions
M-n comint-next-input
M-p comint-previous-input
M-r comint-history-isearch-backward-regexp
RET comint-send-input
TAB completion-at-point

In addition to any hooks its parent mode comint-mode might have run, this mode runs the hook inferior-octave-mode-hook, as the final or penultimate step during initialization.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/octave.el.gz
(define-derived-mode inferior-octave-mode comint-mode "Inferior Octave"
  "Major mode for interacting with an inferior Octave process.

See Info node `(octave-mode) Running Octave from Within Emacs' for more
details.

Key bindings:
\\{inferior-octave-mode-map}"
  :abbrev-table octave-abbrev-table
  :group 'octave

  (setq comint-prompt-regexp inferior-octave-prompt)

  (setq-local comment-use-syntax t)
  (setq-local comment-start octave-comment-start)
  (setq-local comment-end "")
  (setq comment-column 32)
  (setq-local comment-start-skip octave-comment-start-skip)

  (setq font-lock-defaults '(inferior-octave-font-lock-keywords nil nil))

  (setq-local info-lookup-mode 'octave-mode)
  (add-hook 'eldoc-documentation-functions 'octave-eldoc-function nil t)

  (setq-local comint-input-ring-file-name
              (or (getenv "OCTAVE_HISTFILE") "~/.octave_hist"))
  (setq-local comint-input-ring-size
              (string-to-number (or (getenv "OCTAVE_HISTSIZE") "1024")))
  (comint-read-input-ring t)
  (setq-local comint-dynamic-complete-functions
              inferior-octave-dynamic-complete-functions)
  (setq-local comint-prompt-read-only inferior-octave-prompt-read-only)
  (add-hook 'comint-input-filter-functions
            'inferior-octave-directory-tracker nil t)
  ;; http://thread.gmane.org/gmane.comp.gnu.octave.general/48572 [dead link]
  (add-hook 'window-configuration-change-hook
            'inferior-octave-track-window-width-change nil t)
  (setq-local compilation-error-regexp-alist inferior-octave-error-regexp-alist)
  (setq-local compilation-mode-font-lock-keywords
              inferior-octave-compilation-font-lock-keywords)
  (compilation-shell-minor-mode 1)
  (compilation-forget-errors))