Function: ispell-help

ispell-help is an autoloaded and byte-compiled function defined in ispell.el.gz.

Signature

(ispell-help)

Documentation

Display a list of the options available when a misspelling is encountered.

Selections are:

\0..\9 Replace the word with a digit offered in the *Choices* buffer.
\SPC Accept word this time.
\i Accept word and insert into personal dictionary.
\a Accept word for this session.
\A Accept word and place in buffer-local dictionary.
\r Replace word with typed-in value. Rechecked.
\R Replace word with typed-in value. Query-replaced in buffer. Rechecked.
\? Show these commands.
\x Exit spelling buffer. Move cursor to original point.
\X Exit spelling buffer. Leaves cursor at the current point, and permits
         the aborted check to be completed later.
\q Quit spelling session (Kills ispell process).
\l Look up typed-in replacement in alternate dictionary. Wildcards okay.
\u Like \i, but the word is lower-cased first.
\m Place typed-in value in personal dictionary, then recheck current word.
\C-l Redraw screen.
\C-r Recursive edit.
\C-z Suspend Emacs or iconify frame.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/ispell.el.gz
;;;###autoload
(defun ispell-help ()
  "Display a list of the options available when a misspelling is encountered.

Selections are:

\\`0'..\\`9'  Replace the word with a digit offered in the *Choices* buffer.
\\`SPC' Accept word this time.
\\`i'   Accept word and insert into personal dictionary.
\\`a'   Accept word for this session.
\\`A'   Accept word and place in `buffer-local dictionary'.
\\`r'   Replace word with typed-in value.  Rechecked.
\\`R'   Replace word with typed-in value.  Query-replaced in buffer.  Rechecked.
\\`?'   Show these commands.
\\`x'   Exit spelling buffer.  Move cursor to original point.
\\`X'   Exit spelling buffer.  Leaves cursor at the current point, and permits
         the aborted check to be completed later.
\\`q'   Quit spelling session (Kills ispell process).
\\`l'   Look up typed-in replacement in alternate dictionary.  Wildcards okay.
\\`u'   Like \\`i', but the word is lower-cased first.
\\`m'   Place typed-in value in personal dictionary, then recheck current word.
\\`C-l' Redraw screen.
\\`C-r' Recursive edit.
\\`C-z' Suspend Emacs or iconify frame."

  (if (equal ispell-help-in-bufferp 'electric)
      (progn
	(require 'ehelp)
	(with-electric-help
         (lambda ()
           ;;This shouldn't be necessary: with-electric-help needs
           ;; an optional argument telling it about the smallest
           ;; acceptable window-height of the help buffer.
           ;;(if (< (window-height) 15)
           ;;	 (enlarge-window
           ;;	  (- 15 (ispell-adjusted-window-height))))
           (princ
            (substitute-command-keys
             "Selections are:

\\`0'..\\`9'  Replace the word with a digit offered in the *Choices* buffer.
\\`SPC'   Accept word this time.
\\`i'     Accept word and insert into personal dictionary.
\\`a'     Accept word for this session.
\\`A'     Accept word and place in `buffer-local dictionary'.
\\`r'     Replace word with typed-in value.  Rechecked.
\\`R'     Replace word with typed-in value.  Query-replaced in buffer.  Rechecked.
\\`?'     Show these commands.
\\`x'     Exit spelling buffer.  Move cursor to original point.
\\`X'     Exit spelling buffer.  Leaves cursor at the current point, and permits
          the aborted check to be completed later.
\\`q'     Quit spelling session (Kills ispell process).
\\`l'     Look up typed-in replacement in alternate dictionary.  Wildcards okay.
\\`u'     Like \\`i', but the word is lower-cased first.
\\`m'     Place typed-in value in personal dictionary, then recheck current word.
\\`C-l'   Redraw screen.
\\`C-r'   Recursive edit.
\\`C-z'   Suspend Emacs or iconify frame."))
           nil)))


    (let ((help-1 (concat "[r/R]eplace word; [a/A]ccept for this session; "
			  "[i]nsert into personal dictionary"))
	  (help-2 (concat "[l]ook a word up in alternate dictionary;  "
			  "e[x/X]it;  [q]uit session"))
	  (help-3 (concat "[u]ncapitalized insert into dict.  "
			  "Type `x C-h f ispell-help' for more help")))
      (save-window-excursion
	(if ispell-help-in-bufferp
	    (let ((buffer (get-buffer-create "*Ispell Help*")))
	      (with-current-buffer buffer
		(insert (concat help-1 "\n" help-2 "\n" help-3)))
	      (ispell-display-buffer buffer)
	      (sit-for (max 0.5 ispell-help-timeout))
	      (kill-buffer "*Ispell Help*"))
	  (unwind-protect
	      (let ((resize-mini-windows 'grow-only))
		(select-window (minibuffer-window))
		(erase-buffer)
		(message nil)
		;;(set-minibuffer-window (selected-window))
		(enlarge-window 2)
		(insert (concat help-1 "\n" help-2 "\n" help-3))
		(sit-for (max 0.5 ispell-help-timeout)))
	    (erase-buffer)))))))