Function: jit-lock--debug-fontify

jit-lock--debug-fontify is a byte-compiled function defined in jit-lock.el.gz.

Signature

(jit-lock--debug-fontify)

Documentation

Fontify what was deferred for debugging.

Source Code

;; Defined in /usr/src/emacs/lisp/jit-lock.el.gz
(defun jit-lock--debug-fontify ()
  "Fontify what was deferred for debugging."
  (when (and (not jit-lock--debug-fontifying)
             jit-lock-defer-buffers (not memory-full))
    (let ((jit-lock--debug-fontifying t)
          (inhibit-debugger nil))       ;FIXME: Not sufficient!
      ;; Mark the deferred regions back to `fontified = nil'
      (dolist (buffer jit-lock-defer-buffers)
        (when (buffer-live-p buffer)
          (with-current-buffer buffer
            ;; (message "Jit-Debug %s" (buffer-name))
            (with-silent-modifications
                (let ((pos (point-min)))
                  (while
                      (progn
                        (when (eq (get-text-property pos 'fontified) 'defer)
                          (let ((beg pos)
                                (end (setq pos (next-single-property-change
                                                pos 'fontified
                                                nil (point-max)))))
                            (put-text-property beg end 'fontified nil)
                            (jit-lock-fontify-now beg end)))
                        (setq pos (next-single-property-change
                                   pos 'fontified)))))))))
      (setq jit-lock-defer-buffers nil))))