Function: kfill:fallback-fill-paragraph

kfill:fallback-fill-paragraph is a byte-compiled function defined in kfill.el.

Signature

(kfill:fallback-fill-paragraph JUSTIFY-FLAG &optional LEAVE-PREFIX)

Source Code

;; Defined in ~/.emacs.d/elpa/hyperbole-20260414.325/kotl/kfill.el
(defun kfill:fallback-fill-paragraph (justify-flag &optional leave-prefix)
  (save-excursion
    (end-of-line)
    ;; Backward to para begin
    (when (re-search-backward (concat "\\`\\|" paragraph-separate) nil t)
      (kfill:forward-line 1)
      (let* ((region-start (point))
	     (filladapt-mode
	      (if prior-fill-prefix
		  ;; filladapt-mode must be disabled for this command or it
		  ;; will override the removal of prior-fill-prefix.
		  nil
		(or (when (boundp 'filladapt-mode)
		      filladapt-mode)
		    adaptive-fill-mode)))
	     (adaptive-fill-mode filladapt-mode)
	     from)
	(kfill:forward-line -1)
	(setq from (point))
	(forward-paragraph)
	;; Forward to real paragraph end
	(when (re-search-forward (concat "\\'\\|" paragraph-separate) nil t)
	  (unless (= (point) (point-max))
	    (beginning-of-line))
	  (unless leave-prefix
	    ;; Remove any leading occurrences of `prior-fill-prefix'.
	    (kfill:replace-string prior-fill-prefix "" nil region-start (point)))
	  (or (and fill-paragraph-function
		   (not (eq fill-paragraph-function t))
		   (let ((func fill-paragraph-function)
			 fill-paragraph-function)
		     (goto-char region-start)
		     (funcall func justify-flag)))
	      (fill-region-as-paragraph from (point) justify-flag)))))))