Function: lisp--el-match-keyword@llama

lisp--el-match-keyword@llama is a byte-compiled function defined in llama.el.

Signature

(lisp--el-match-keyword@llama LIMIT)

Documentation

Highlight symbols following "(##" the same as if they followed "(".

Source Code

;; Defined in ~/.emacs.d/elpa/llama-20260301.1253/llama.el
(defun lisp--el-match-keyword@llama (limit)
  "Highlight symbols following \"(##\" the same as if they followed \"(\"."
  (catch 'found
    (while (re-search-forward
            (concat "(\\(?:## ?\\)?\\("
                    (static-if (get 'lisp-mode-symbol 'rx-definition) ;>= 29.1
                        (rx lisp-mode-symbol)
                      lisp-mode-symbol-regexp)
                    "\\)\\_>")
            limit t)
      (let ((sym (intern-soft (match-string 1))))
        (when (and (or (special-form-p sym)
                       (macrop sym)
                       (and (bound-and-true-p morlock-mode)
                            ;; Same as in advice of `morlock' package.
                            (get sym 'morlock-font-lock-keyword)))
                   (not (get sym 'no-font-lock-keyword))
                   (static-if (fboundp 'lisp--el-funcall-position-p) ;>= 28.1
                       (lisp--el-funcall-position-p (match-beginning 0))
                     (not (lisp--el-non-funcall-position-p
                           (match-beginning 0)))))
          (throw 'found t))))))