Function: loaddefs-generate--compute-prefixes

loaddefs-generate--compute-prefixes is a byte-compiled function defined in loaddefs-gen.el.gz.

Signature

(loaddefs-generate--compute-prefixes LOAD-NAME)

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/loaddefs-gen.el.gz
(defun loaddefs-generate--compute-prefixes (load-name)
  (goto-char (point-min))
  (let ((prefs nil)
        (temp-obarray (obarray-make)))
    ;; Avoid (defvar <foo>) by requiring a trailing space.
    (while (re-search-forward
            "^(\\(def[^ \t\n]+\\)[ \t\n]+['(]*\\([^' ()\"\n]+\\)[\n \t]" nil t)
      (unless (member (match-string 1) autoload-ignored-definitions)
        (let* ((name (match-string-no-properties 2))
               ;; Consider `read-symbol-shorthands'.
               (probe (let ((obarray temp-obarray))
                        (car (read-from-string name)))))
          (when (symbolp probe)
            (setq name (symbol-name probe))
            (when (save-excursion
                    (goto-char (match-beginning 0))
                    (or (bobp)
                        (progn
                          (forward-line -1)
                          (not (looking-at ";;;###autoload")))))
              (push name prefs))))))
    (loaddefs-generate--make-prefixes prefs load-name)))