Function: loaddefs-generate--emacs-batch

loaddefs-generate--emacs-batch is a byte-compiled function defined in loaddefs-gen.el.gz.

Signature

(loaddefs-generate--emacs-batch)

Documentation

Generate the loaddefs for the Emacs build.

This is like loaddefs-generate-batch, but has some specific rules for built-in packages and excluded files.

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/loaddefs-gen.el.gz
(defun loaddefs-generate--emacs-batch ()
  "Generate the loaddefs for the Emacs build.
This is like `loaddefs-generate-batch', but has some specific
rules for built-in packages and excluded files."
  (let* ((args (mapcar #'file-truename command-line-args-left))
         ;; We're run from $BUILDDIR/lisp but all the .el(c) files reside
         ;; (and are generated) in `lisp-directory' which is in $SRCDIR,
         ;; so go there and don't look back.
         (default-directory (file-truename lisp-directory))
         (output-file (expand-file-name "loaddefs.el")))
    (setq command-line-args-left nil)
    (loaddefs-generate
     args output-file
     (loaddefs-generate--excluded-files)
     nil t
     ;; Always do a complete update if loaddefs-gen.el has been
     ;; updated.
     (file-newer-than-file-p
      (expand-file-name "emacs-lisp/loaddefs-gen.el" lisp-directory)
      output-file))
    (let ((lisp-mode-autoload-regexp
           "^;;;###\\(\\(noexist\\)-\\)?\\(theme-autoload\\)"))
      (loaddefs-generate
       (expand-file-name "../etc/themes/")
       (expand-file-name "theme-loaddefs.el")))))