Function: magit--insert-modules-overview

magit--insert-modules-overview is a byte-compiled function defined in magit-submodule.el.

Signature

(magit--insert-modules-overview &optional SECTION)

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-submodule.el
(defun magit--insert-modules-overview (&optional _section)
  (magit-with-toplevel
    (let* ((modules (magit-list-module-paths))
           (path-format (format "%%-%ds "
                                (min (apply #'max (mapcar #'length modules))
                                     (/ (window-width) 2))))
           (branch-format (format "%%-%ds " (min 25 (/ (window-width) 3)))))
      (dolist (module modules)
        (let ((default-directory
               (expand-file-name (file-name-as-directory module))))
          (magit-insert-section (module module t)
            (insert (propertize (format path-format module)
                                'font-lock-face 'magit-diff-file-heading))
            (if (not (file-exists-p ".git"))
                (insert "(unpopulated)")
              (insert
               (format
                branch-format
                (if-let ((branch (magit-get-current-branch)))
                    (propertize branch 'font-lock-face 'magit-branch-local)
                  (propertize "(detached)" 'font-lock-face 'warning))))
              (cond-let
                ([desc (magit-git-string "describe" "--tags")]
                 (when (and magit-modules-overview-align-numbers
                            (string-match-p "\\`[0-9]" desc))
                   (insert ?\s))
                 (insert (propertize desc 'font-lock-face 'magit-tag)))
                ([abbrev (magit-rev-format "%h")]
                 (insert (propertize abbrev 'font-lock-face 'magit-hash)))))
            (insert ?\n))))))
  (insert ?\n))