Function: magit-auto-revert-mode--initialize

magit-auto-revert-mode--initialize is a byte-compiled function defined in magit-autorevert.el.

Signature

(magit-auto-revert-mode--initialize SYMBOL VALUE)

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-autorevert.el
;;; Mode

;;;###autoload
(progn ; magit-auto-revert-mode--initialize
  (defun magit-auto-revert-mode--initialize (symbol value)
    (internal--define-uninitialized-variable symbol)
    (if (not load-file-name)
        (custom-initialize-set symbol value)
      ;; Bugs in package managers prevent the use of lexical
      ;; bindings in autoloaded code.  See #5476 and #5485.
      (defalias 'magit-auto-revert-mode--after-load
        (apply-partially
         (lambda (symbol value mode-file file)
           (when (equal file mode-file)
             (remove-hook 'after-load-functions
                          'magit-auto-revert-mode--after-load)
             (fmakunbound 'magit-auto-revert-mode--after-load)
             (if after-init-time
                 (custom-initialize-set symbol value)
               ;; Delay activation in case the user disables the mode
               ;; after loading this library but still during startup.
               (defalias 'magit-auto-revert-mode--after-init
                 (apply-partially
                  (lambda (symbol value)
                    (remove-hook 'after-init-hook
                                 'magit-auto-revert-mode--after-init)
                    (fmakunbound 'magit-auto-revert-mode--after-init)
                    (custom-initialize-set symbol value))
                  symbol value))
               (add-hook 'after-init-hook 'magit-auto-revert-mode--after-init))))
         symbol value load-file-name))
      (add-hook 'after-load-functions 'magit-auto-revert-mode--after-load))))