Function: magit-display-buffer-fullcolumn-most-v1

magit-display-buffer-fullcolumn-most-v1 is a byte-compiled function defined in magit-mode.el.

Signature

(magit-display-buffer-fullcolumn-most-v1 BUFFER)

Documentation

Display BUFFER using the full column except in some cases.

For most cases where BUFFER's major-mode derives from magit-mode, display it in the selected window and grow that window to the full height of the frame, deleting other windows in that column as necessary. However, display BUFFER in another window if 1) BUFFER's mode derives from magit-process-mode, or
2) BUFFER's mode derives from magit-diff-mode, provided that
the mode of the current buffer derives from magit-log-mode or magit-cherry-mode.

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-mode.el
(defun magit-display-buffer-fullcolumn-most-v1 (buffer)
  "Display BUFFER using the full column except in some cases.
For most cases where BUFFER's `major-mode' derives from
`magit-mode', display it in the selected window and grow that
window to the full height of the frame, deleting other windows in
that column as necessary.  However, display BUFFER in another
window if 1) BUFFER's mode derives from `magit-process-mode', or
2) BUFFER's mode derives from `magit-diff-mode', provided that
the mode of the current buffer derives from `magit-log-mode' or
`magit-cherry-mode'."
  (display-buffer
   buffer
   (cond ((and (or (bound-and-true-p git-commit-mode)
                   (derived-mode-p 'magit-log-mode
                                   'magit-cherry-mode
                                   'magit-reflog-mode))
               (with-current-buffer buffer
                 (derived-mode-p 'magit-diff-mode)))
          nil)
         ((with-current-buffer buffer
            (derived-mode-p 'magit-process-mode))
          nil)
         ('(magit--display-buffer-fullcolumn)))))