Function: magit-process--format-arguments

magit-process--format-arguments is a byte-compiled function defined in magit-process.el.

Signature

(magit-process--format-arguments PROGRAM ARGS)

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-process.el
(defun magit-process--format-arguments (program args)
  (cond
    ((and args (equal program (magit-git-executable)))
     (let ((global (magit-process-git-arguments--length)))
       (concat
        (propertize (file-name-nondirectory program)
                    'font-lock-face 'magit-section-heading)
        " "
        (propertize (magit--ellipsis)
                    'font-lock-face 'magit-section-heading
                    'help-echo (string-join (seq-take args global) " "))
        " "
        (propertize (mapconcat #'shell-quote-argument (seq-drop args global) " ")
                    'font-lock-face 'magit-section-heading))))
    ((and args (equal program shell-file-name))
     (propertize (cadr args)
                 'font-lock-face 'magit-section-heading))
    ((concat (propertize (file-name-nondirectory program)
                         'font-lock-face 'magit-section-heading)
             " "
             (propertize (mapconcat #'shell-quote-argument args " ")
                         'font-lock-face 'magit-section-heading)))))