Function: magit-remote-add

magit-remote-add is an autoloaded, interactive and byte-compiled function defined in magit-remote.el.

Signature

(magit-remote-add REMOTE URL &optional ARGS)

Documentation

Add a remote named REMOTE and fetch it.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-remote.el
;;;###autoload
(defun magit-remote-add (remote url &optional args)
  "Add a remote named REMOTE and fetch it."
  (interactive
    (let ((origin (magit-get "remote.origin.url"))
          (remote (magit-read-string-ns "Remote name")))
      (list remote
            (magit-read-url
             "Remote url"
             (and origin
                  (string-match "\\([^:/]+\\)/[^/]+\\(\\.git\\)?\\'" origin)
                  (replace-match remote t t origin 1)))
            (transient-args 'magit-remote))))
  (cond ((pcase (list magit-remote-add-set-remote.pushDefault
                      (magit-get "remote.pushDefault"))
           (`(,(pred stringp) ,_) t)
           ((or `(ask ,_) '(ask-if-unset nil))
            (y-or-n-p (format "Set `remote.pushDefault' to \"%s\"? " remote))))
         (magit-call-git "remote" "add" args remote url)
         (setf (magit-get "remote.pushDefault") remote)
         (magit-refresh))
        ((magit-run-git-async "remote" "add" args remote url))))