Function: mail-directory

mail-directory is a byte-compiled function defined in mailalias.el.gz.

Signature

(mail-directory PREFIX)

Documentation

Use mail-directory facility to get user names matching PREFIX.

If PREFIX is nil, get all the defined user names. This function calls mail-directory-function to query the directory, then uses mail-directory-parser to parse the output it returns.

Source Code

;; Defined in /usr/src/emacs/lisp/mail/mailalias.el.gz
(defun mail-directory (prefix)
  "Use mail-directory facility to get user names matching PREFIX.
If PREFIX is nil, get all the defined user names.
This function calls `mail-directory-function' to query the directory,
then uses `mail-directory-parser' to parse the output it returns."
  (message "Querying directory...")
  (with-current-buffer (generate-new-buffer " *mail-directory*")
    (funcall mail-directory-function prefix)
    (goto-char (point-min))
    (let (directory)
      (if (stringp mail-directory-parser)
	  (while (re-search-forward mail-directory-parser nil t)
	    (push (match-string 1) directory))
	(if mail-directory-parser
	    (setq directory (funcall mail-directory-parser))
	  (while (not (eobp))
	    (push (buffer-substring (point)
                                    (progn
                                      (forward-line)
                                      (if (bolp)
                                          (1- (point))
                                        (point))))
                  directory))))
      (kill-buffer (current-buffer))
      (message "Querying directory...done")
      directory)))