Function: mairix-widget-create-query

mairix-widget-create-query is a byte-compiled function defined in mairix.el.gz.

Signature

(mairix-widget-create-query &optional VALUES)

Documentation

Create widgets for creating mairix queries.

Fill in VALUES if based on an article.

Source Code

;; Defined in /usr/src/emacs/lisp/net/mairix.el.gz
(defun mairix-widget-create-query (&optional values)
  "Create widgets for creating mairix queries.
Fill in VALUES if based on an article."
  (when (get-buffer mairix-customize-query-buffer)
    (kill-buffer mairix-customize-query-buffer))
  (switch-to-buffer mairix-customize-query-buffer)
  (kill-all-local-variables)
  (erase-buffer)
  (widget-insert
   "Specify your query for Mairix using check boxes for activating fields.\n\n")
  (widget-insert
   (concat "Use ~word        to match messages "
	   (propertize "not" 'face 'italic)
	   " containing the word)\n"
	   "    substring=   to match words containing the substring\n"
	   "    substring=N  to match words containing the substring, allowing\n"
	   "                  up to N errors(missing/extra/different letters)\n"
	   "    ^substring=  to match the substring at the beginning of a word.\n"))
  (widget-insert
   (format-message
    "Whitespace will be converted to `,' (i.e. AND).  Use `/' for OR.\n\n"))
  (setq mairix-widgets (mairix-widget-build-editable-fields values))
  (when (member 'flags mairix-widget-other)
    (widget-insert "\nFlags:\n      Seen:     ")
    (mairix-widget-add "seen"
		       'menu-choice
		       :value "ignore"
		       '(item "yes") '(item "no") '(item "ignore"))
    (widget-insert "      Replied:  ")
    (mairix-widget-add "replied"
		       'menu-choice
		       :value "ignore"
		       '(item "yes") '(item "no") '(item "ignore"))
    (widget-insert "      Ticked:   ")
    (mairix-widget-add "flagged"
		       'menu-choice
		       :value "ignore"
		       '(item "yes") '(item "no") '(item "ignore")))
  (when (member 'threads mairix-widget-other)
    (widget-insert "\n")
    (mairix-widget-add "Threads" 'checkbox nil))
  (widget-insert " Show full threads\n\n"))