Function: mark-sexp

mark-sexp is an interactive and byte-compiled function defined in lisp.el.gz.

Signature

(mark-sexp &optional ARG ALLOW-EXTEND)

Documentation

Set mark ARG sexps from point or move mark one sexp.

When called from Lisp with ALLOW-EXTEND omitted or nil, mark is set ARG sexps from point. With ARG and ALLOW-EXTEND both non-nil (interactively, with prefix argument), the place to which mark goes is the same place C-M-f (forward-sexp) would move to with the same argument; if the mark is active, it moves ARG sexps from its current position, otherwise it is set ARG sexps from point. When invoked interactively without a prefix argument and no active region, mark moves one sexp forward. When invoked interactively without a prefix argument, and region is active, mark moves one sexp away of point (i.e., forward if mark is at or after point, back if mark is before point), thus extending the region by one sexp. Since the direction of region extension depends on the relative position of mark and point, you can change the direction by C-x C-x (exchange-point-and-mark). This command assumes point is not in a string or comment.

View in manual

Probably introduced at or before Emacs version 21.1.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/emacs-lisp/lisp.el.gz
(defun mark-sexp (&optional arg allow-extend)
  "Set mark ARG sexps from point or move mark one sexp.
When called from Lisp with ALLOW-EXTEND omitted or nil, mark is
set ARG sexps from point.
With ARG and ALLOW-EXTEND both non-nil (interactively, with prefix
argument), the place to which mark goes is the same place \\[forward-sexp]
would move to with the same argument; if the mark is active, it moves
ARG sexps from its current position, otherwise it is set ARG sexps
from point.
When invoked interactively without a prefix argument and no active
region, mark moves one sexp forward.
When invoked interactively without a prefix argument, and region
is active, mark moves one sexp away of point (i.e., forward
if mark is at or after point, back if mark is before point), thus
extending the region by one sexp.  Since the direction of region
extension depends on the relative position of mark and point, you
can change the direction by \\[exchange-point-and-mark].
This command assumes point is not in a string or comment."
  (interactive "P\np")
  (cond ((and allow-extend
	      (or (and (eq last-command this-command) (mark t))
		  (and transient-mark-mode mark-active)))
	 (setq arg (if arg (prefix-numeric-value arg)
		     (if (< (mark) (point)) -1 1)))
	 (set-mark
	  (save-excursion
	    (goto-char (mark))
            (condition-case error
                (forward-sexp arg)
              (scan-error
               (user-error (if (equal (cadr error)
                                      "Containing expression ends prematurely")
                               "No more sexp to select"
                             (cadr error)))))
	    (point))))
	(t
	 (push-mark
	  (save-excursion
            (condition-case error
                (forward-sexp (prefix-numeric-value arg))
              (scan-error
               (user-error (if (equal (cadr error)
                                      "Containing expression ends prematurely")
                               "No sexp to select"
                             (cadr error)))))
	    (point))
	  nil t))))