Function: markdown-match-bold

markdown-match-bold is a byte-compiled function defined in markdown-mode.el.

Signature

(markdown-match-bold LAST)

Documentation

Match inline bold from the point to LAST.

Source Code

;; Defined in ~/.emacs.d/elpa/markdown-mode-20260321.143/markdown-mode.el
(defun markdown-match-bold (last)
  "Match inline bold from the point to LAST."
  (let (done
        retval
        last-inline-code)
    (while (not done)
      (if (markdown-match-inline-generic markdown-regex-bold last)
          (let ((is-gfm (derived-mode-p 'gfm-mode))
                (begin (match-beginning 2))
                (end (match-end 2)))
            (if (or
                 (and last-inline-code
                      (>= begin (car last-inline-code))
                      (< begin (cdr last-inline-code)))
                 (save-match-data
                   (when (markdown-inline-code-at-pos begin (cdr last-inline-code))
                     (setq last-inline-code `(,(match-beginning 0) . ,(match-end 0)))))
                 (markdown-inline-code-at-pos-p end)
                 (markdown-in-comment-p)
                 (markdown-range-property-any
                  begin begin 'face '(markdown-url-face
                                      markdown-plain-url-face))
                 (markdown-range-property-any
                  begin end 'face '(markdown-hr-face
                                    markdown-math-face))
                 (and is-gfm (not (markdown--gfm-markup-underscore-p begin end))))
                (progn (goto-char (min (1+ begin) last))
                       (unless (< (point) last)
                         (setq
                          done t)))
              (set-match-data (list (match-beginning 2) (match-end 2)
                                    (match-beginning 3) (match-end 3)
                                    (match-beginning 4) (match-end 4)
                                    (match-beginning 5) (match-end 5)))
              (setq done t
                    retval t)))
        (setq done t)))
    retval))