Function: markdown-ts--in-table-mode-update-ov

markdown-ts--in-table-mode-update-ov is a byte-compiled function defined in markdown-ts-mode.el.gz.

Signature

(markdown-ts--in-table-mode-update-ov)

Documentation

Manage markdown-ts--in-table-mode-ov.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/markdown-ts-mode.el.gz
(defun markdown-ts--in-table-mode-update-ov ()
  "Manage `markdown-ts--in-table-mode-ov'."
  (cond (markdown-ts-in-table-mode
         (when-let* ((at-table (markdown-ts-at-table-p nil t))
                     (table (cdr at-table))
                     (beg (treesit-node-start table))
                     (end (treesit-node-end table)))
           (if markdown-ts--in-table-mode-ov
               ;; Move the overlay, if needed, and reset the tick if so.
               (unless (and (eq (overlay-start markdown-ts--in-table-mode-ov) beg)
                            (eq (overlay-end markdown-ts--in-table-mode-ov) end))
                 (move-overlay markdown-ts--in-table-mode-ov beg end)
                 (overlay-put markdown-ts--in-table-mode-ov
                              'markdown-ts-in-table-tick nil))
             (setq markdown-ts--in-table-mode-ov
                   (make-overlay beg end nil t t))
             (overlay-put markdown-ts--in-table-mode-ov
                          'markdown-ts-in-table t)
             (overlay-put markdown-ts--in-table-mode-ov
                          'evaporate t)
             (overlay-put markdown-ts--in-table-mode-ov
                          'priority '(nil . 20))
             (overlay-put markdown-ts--in-table-mode-ov
                          'face 'markdown-ts-in-table))))
        (t
         (when markdown-ts--in-table-mode-ov
           (delete-overlay markdown-ts--in-table-mode-ov)))))