Function: mh-update-sequences

mh-update-sequences is an autoloaded, interactive and byte-compiled function defined in mh-folder.el.gz.

Signature

(mh-update-sequences)

Documentation

Flush MH-E's state out to MH.

This function updates the sequence specified by your
"Unseen-Sequence:" profile component, "cur", and the sequence
listed by the mh-tick-seq option which is "tick" by default. The message at the cursor is used for "cur".

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/mh-e/mh-folder.el.gz
;;;###mh-autoload
(defun mh-update-sequences ()
  "Flush MH-E's state out to MH.

This function updates the sequence specified by your
\"Unseen-Sequence:\" profile component, \"cur\", and the sequence
listed by the `mh-tick-seq' option which is \"tick\" by default.
The message at the cursor is used for \"cur\"."
  (interactive)
  ;; mh-update-sequences is the opposite of mh-read-folder-sequences,
  ;; which updates MH-E's state from MH.
  (let ((folder-set (mh-update-unseen))
        (new-cur (mh-get-msg-num nil)))
    (if new-cur
        (let ((seq-entry (mh-find-seq 'cur)))
          (mh-remove-cur-notation)
          (if seq-entry
              (setcdr seq-entry (list new-cur))
            (mh-add-msgs-to-seq (list new-cur) 'cur))
          (mh-define-sequence 'cur (list new-cur))
          (beginning-of-line)
          (if (looking-at mh-scan-good-msg-regexp)
              (mh-notate-cur)))
      (or folder-set
          (save-excursion
            ;; psg - mh-current-folder is nil if mh-summary-height < 4 !
            ;;       So I added this sanity check.
            (if (stringp mh-current-folder)
                (mh-exec-cmd-quiet t "folder" mh-current-folder "-fast")
              (mh-exec-cmd-quiet t "folder" "-fast")))))))