Function: mml2015-mailcrypt-encrypt

mml2015-mailcrypt-encrypt is a byte-compiled function defined in mml2015.el.gz.

Signature

(mml2015-mailcrypt-encrypt CONT &optional SIGN)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/mml2015.el.gz
(defun mml2015-mailcrypt-encrypt (cont &optional sign)
  (let ((mc-pgp-always-sign
	 (or mc-pgp-always-sign
	     sign
	     (eq t (or (message-options-get 'message-sign-encrypt)
		       (message-options-set
			'message-sign-encrypt
			(or (y-or-n-p "Sign the message? ")
			    'not))))
	     'never)))
    (insert
     (with-temp-buffer
       (set-buffer-multibyte nil)
       (mc-encrypt-generic
	(or (message-options-get 'message-recipients)
	    (message-options-set 'message-recipients
				 (mc-cleanup-recipient-headers
				  (read-string "Recipients: "))))
	nil nil nil
	(message-options-get 'message-sender))
       (buffer-string))))
  (goto-char (point-min))
  (unless (looking-at "-----BEGIN PGP MESSAGE-----")
    (error "Fail to encrypt the message"))
  (let ((boundary (mml-compute-boundary cont)))
    (insert (format "Content-Type: multipart/encrypted; boundary=\"%s\";\n"
		    boundary))
    (insert "\tprotocol=\"application/pgp-encrypted\"\n\n")
    (insert (format "--%s\n" boundary))
    (insert "Content-Type: application/pgp-encrypted\n\n")
    (insert "Version: 1\n\n")
    (insert (format "--%s\n" boundary))
    (insert "Content-Type: application/octet-stream\n\n")
    (goto-char (point-max))
    (insert (format "--%s--\n" boundary))
    (goto-char (point-max))))