Function: mouse-generate-font-name-for-menu

mouse-generate-font-name-for-menu is a byte-compiled function defined in mouse.el.gz.

Signature

(mouse-generate-font-name-for-menu ENTITY)

Documentation

Return a short name for font entity ENTITY.

The name should be used to describe ENTITY in the case that its family is already known, such as in a pane generated by mouse-generate-font-menu.

Source Code

;; Defined in /usr/src/emacs/lisp/mouse.el.gz
(defun mouse-generate-font-name-for-menu (entity)
  "Return a short name for font entity ENTITY.
The name should be used to describe ENTITY in the case that its
family is already known, such as in a pane generated by
`mouse-generate-font-menu'."
  (let ((weight (font-get entity :weight))
        (slant (font-get entity :slant))
        (width (font-get entity :width))
        (size (font-get entity :size))
        (adstyle (font-get entity :adstyle))
        (name ""))
    (when weight
      (setq name (concat name (symbol-name weight) " ")))
    (when (and slant
               (not (eq slant 'normal)))
      (setq name (concat name (symbol-name slant) " ")))
    (when (and width (not (eq width 'normal)))
      (setq name (concat name (symbol-name width) " ")))
    (when (and size (not (zerop size)))
      (setq name (concat name (number-to-string size) " ")))
    (when adstyle
      (setq name (concat name (if (symbolp adstyle)
                                  (symbol-name adstyle)
                                (number-to-string adstyle))
                         " ")))
    (string-trim-right name)))